benbot/nvim-treesitter
1
0
Fork 0
mirror of https://github.com/nvim-treesitter/nvim-treesitter.git synced 2026-07-18 11:20:07 -04:00
Code Issues Projects Releases Packages Wiki Activity Actions

feat!: drop modules, general refactor and cleanup

Browse source
This commit is contained in:
Christian Clason 2023-06-12 09:54:30 -06:00
parent 310f0925ec
commit 692b051b09
1247 changed files with 6096 additions and 9074 deletions
Download patch file Download diff file Expand all files Collapse all files

81
runtime/queries/yaml/injections.scm Normal file
View file

@ -0,0 +1,81 @@
((comment) @injection.content
(#set! injection.language "comment"))
; Github actions ("run") / Gitlab CI ("scripts")
; Taskfile scripts ("cmds", "cmd", "sh")
(block_mapping_pair
key: (flow_node) @_run
(#any-of? @_run "run" "script" "before_script" "after_script" "cmds" "cmd" "sh")
value: (flow_node
(plain_scalar
(string_scalar) @injection.content)
(#set! injection.language "bash")))
(block_mapping_pair
key: (flow_node) @_run
(#any-of? @_run "run" "script" "before_script" "after_script" "cmds" "cmd" "sh")
value: (block_node
(block_scalar) @injection.content
(#set! injection.language "bash")
(#offset! @injection.content 0 1 0 0)))
(block_mapping_pair
key: (flow_node) @_run
(#any-of? @_run "run" "script" "before_script" "after_script" "cmds" "sh")
value: (block_node
(block_sequence
(block_sequence_item
(flow_node
(plain_scalar
(string_scalar) @injection.content))
(#set! injection.language "bash")))))
(block_mapping_pair
key: (flow_node) @_run
(#any-of? @_run "script" "before_script" "after_script" "cmds" "sh")
value: (block_node
(block_sequence
(block_sequence_item
(block_node
(block_scalar) @injection.content
(#set! injection.language "bash")
(#offset! @injection.content 0 1 0 0))))))
; Prometheus Alertmanager ("expr")
(block_mapping_pair
key: (flow_node) @_expr
(#eq? @_expr "expr")
value: (flow_node
(plain_scalar
(string_scalar) @injection.content)
(#set! injection.language "promql")))
(block_mapping_pair
key: (flow_node) @_expr
(#eq? @_expr "expr")
value: (block_node
(block_scalar) @injection.content
(#set! injection.language "promql")
(#offset! @injection.content 0 1 0 0)))
(block_mapping_pair
key: (flow_node) @_expr
(#eq? @_expr "expr")
value: (block_node
(block_sequence
(block_sequence_item
(flow_node
(plain_scalar
(string_scalar) @injection.content))
(#set! injection.language "promql")))))
(block_mapping_pair
key: (flow_node) @_expr
(#eq? @_expr "expr")
value: (block_node
(block_sequence
(block_sequence_item
(block_node
(block_scalar) @injection.content
(#set! injection.language "promql")
(#offset! @injection.content 0 1 0 0))))))