feat!: drop modules, general refactor and cleanup

runtime/queries/snakemake/folds.scm

@@ -0,0 +1,8 @@
+; inherits: python
+
+[
+  (rule_definition)
+  (rule_inheritance)
+  (module_definition)
+  (checkpoint_definition)
+] @fold

runtime/queries/snakemake/highlights.scm

@@ -0,0 +1,82 @@
+; inherits: python
+
+; Compound directives
+[
+  "rule"
+  "checkpoint"
+  "module"
+] @keyword
+
+; Top level directives (eg. configfile, include)
+(module
+  (directive
+    name: _ @keyword))
+
+; Subordinate directives (eg. input, output)
+body: (_
+  (directive
+    name: _ @label))
+
+; rule/module/checkpoint names
+(rule_definition
+  name: (identifier) @type)
+
+(module_definition
+  name: (identifier) @type)
+
+(checkpoint_definition
+  name: (identifier) @type)
+
+; Rule imports
+(rule_import
+  [
+    "use"
+    "rule"
+    "from"
+    "exclude"
+    "as"
+    "with"
+  ] @keyword.import)
+
+; Rule inheritance
+(rule_inheritance
+  "use" @keyword
+  "rule" @keyword
+  "with" @keyword)
+
+; Wildcard names
+(wildcard
+  (identifier) @variable)
+
+(wildcard
+  (flag) @variable.parameter.builtin)
+
+; builtin variables
+((identifier) @variable.builtin
+  (#any-of? @variable.builtin "checkpoints" "config" "gather" "rules" "scatter" "workflow"))
+
+; References to directive labels in wildcard interpolations
+; the #any-of? queries are moved above the #has-ancestor? queries to
+; short-circuit the potentially expensive tree traversal, if possible
+; see:
+; https://github.com/nvim-treesitter/nvim-treesitter/pull/4302#issuecomment-1685789790
+; directive labels in wildcard context
+((wildcard
+  (identifier) @label)
+  (#any-of? @label "input" "log" "output" "params" "resources" "threads" "wildcards"))
+
+((wildcard
+  (attribute
+    object: (identifier) @label))
+  (#any-of? @label "input" "log" "output" "params" "resources" "threads" "wildcards"))
+
+((wildcard
+  (subscript
+    value: (identifier) @label))
+  (#any-of? @label "input" "log" "output" "params" "resources" "threads" "wildcards"))
+
+; directive labels in block context (eg. within 'run:')
+((identifier) @label
+  (#any-of? @label "input" "log" "output" "params" "resources" "threads" "wildcards")
+  (#has-ancestor? @label "directive")
+  (#has-ancestor? @label "block"))

runtime/queries/snakemake/indents.scm

@@ -0,0 +1,25 @@
+; inherits: python
+
+((rule_definition) @indent.begin
+  (#set! indent.immediate 1))
+
+((checkpoint_definition) @indent.begin
+  (#set! indent.immediate 1))
+
+((rule_inheritance) @indent.begin
+  (#set! indent.immediate 1))
+
+((rule_import
+  "with"
+  ":") @indent.begin
+  (#set! indent.immediate 1))
+
+((module_definition) @indent.begin
+  (#set! indent.immediate 1))
+
+((directive) @indent.begin
+  (#set! indent.immediate 1))
+
+; end indentation after last parameter node (no following ',')
+(directive_parameters
+  (_) @indent.end .)

runtime/queries/snakemake/injections.scm

@@ -0,0 +1,5 @@
+; inherits: python
+
+(wildcard
+  (constraint) @injection.content
+  (#set! injection.language "regex"))

runtime/queries/snakemake/locals.scm

@@ -0,0 +1,4 @@
+; inherits: python
+
+(rule_definition
+  name: (identifier) @local.definition.type) @local.scope