benbot/nvim-treesitter
1
0
Fork 0
mirror of https://github.com/nvim-treesitter/nvim-treesitter.git synced 2026-07-19 03:40:04 -04:00
Code Issues Projects Releases Packages Wiki Activity Actions 2

feat!: drop modules, general refactor and cleanup

Browse source
This commit is contained in:
Christian Clason 2023-06-12 09:54:30 -06:00
parent 310f0925ec
commit 692b051b09
1247 changed files with 6096 additions and 9074 deletions
Download patch file Download diff file Expand all files Collapse all files

117
runtime/queries/slint/locals.scm Normal file
View file

@ -0,0 +1,117 @@
[
(anon_struct_block)
(block)
(callback_event)
(component)
(enum_block)
(function_definition)
(global_definition)
(imperative_block)
(struct_block)
] @local.scope
(anon_struct_block
(_) @local.definition.field)
(argument) @local.definition.var
(callback
name: (_) @local.definition.field)
(component_definition
name: (_) @local.definition.type)
(enum_definition
name: (_) @local.definition.type)
(enum_block
(_) @local.definition.field)
(function_definition
name: (_) @local.definition.function)
(global_definition
name: (_) @local.definition.type)
(import_type
import_name: (_)
!local_name) @local.definition.import
(import_type
import_name: (_)
local_name: (_) @local.definition.import)
(property
name: (_) @local.definition.field)
(struct_block
(_) @local.definition.field)
(struct_definition
name: (_) @local.definition.type)
(typed_identifier
name: (_) @local.definition.var)
(argument
(_) @local.reference)
(binary_expression
left: (_) @local.reference)
(binary_expression
right: (_) @local.reference)
(callback_event
name: (_) @local.reference)
(component
type: (_) @local.reference
(#set! reference.kind "type"))
(component_definition
base_type: (_) @local.reference
(#set! reference.kind "type"))
(function_call
name: (_) @local.reference)
(index_op
index: (_) @local.reference)
(index_op
left: (_) @local.reference)
(member_access
base: (_) @local.reference)
(member_access
member: (_) @local.reference)
(parens_op
left: (_) @local.reference)
(property
type: (_) @local.reference
(#set! reference.kind "type"))
(property_assignment
property: (_) @local.reference
(#set! reference.kind "field"))
(property_assignment
value: (_) @local.reference)
(struct_block
(_) @local.reference
(#set! reference.kind "type"))
(tr
percent: (_) @local.reference)
(typed_identifier
type: (_) @local.reference
(#set! reference.kind "type"))
(unary_expression
left: (_) @local.reference)