feat!: drop modules, general refactor and cleanup

runtime/queries/ron/folds.scm

@@ -0,0 +1,7 @@
+[
+  (array)
+  (map)
+  (tuple)
+  (struct)
+  (block_comment)
+] @fold

runtime/queries/ron/highlights.scm

@@ -0,0 +1,62 @@
+; Structs
+;------------
+(enum_variant) @constant
+
+(struct_entry
+  (identifier) @variable.member)
+
+(struct_entry
+  (enum_variant
+    (identifier) @constant))
+
+(struct_name
+  (identifier)) @type
+
+(unit_struct) @type.builtin
+
+; Literals
+;------------
+(string) @string
+
+(boolean) @boolean
+
+(integer) @number
+
+(float) @number.float
+
+(char) @character
+
+; Comments
+;------------
+[
+  (line_comment)
+  (block_comment)
+] @comment @spell
+
+; Punctuation
+;------------
+[
+  "{"
+  "}"
+] @punctuation.bracket
+
+[
+  "("
+  ")"
+] @punctuation.bracket
+
+[
+  "["
+  "]"
+] @punctuation.bracket
+
+[
+  ","
+  ":"
+] @punctuation.delimiter
+
+"-" @operator
+
+; Special
+;------------
+(escape_sequence) @string.escape

runtime/queries/ron/indents.scm

@@ -0,0 +1,21 @@
+[
+  (array)
+  (map)
+  (tuple)
+  (struct)
+] @indent.begin
+
+[
+  "{"
+  "}"
+] @indent.branch
+
+[
+  "("
+  ")"
+] @indent.branch
+
+[
+  "["
+  "]"
+] @indent.branch

runtime/queries/ron/injections.scm

@@ -0,0 +1,5 @@
+([
+  (line_comment)
+  (block_comment)
+] @injection.content
+  (#set! injection.language "comment"))

runtime/queries/ron/locals.scm

@@ -0,0 +1,25 @@
+(source_file) @local.scope
+
+(source_file
+  (array) @local.scope)
+
+(source_file
+  (map) @local.scope)
+
+(source_file
+  (struct) @local.scope)
+
+(source_file
+  (tuple) @local.scope)
+
+(identifier) @local.reference
+
+(struct_entry
+  (identifier) @local.definition.field)
+
+(struct_entry
+  (identifier) @local.definition.enum
+  (enum_variant))
+
+(struct
+  (struct_name) @local.definition.type)