feat!: drop modules, general refactor and cleanup

runtime/queries/readline/folds.scm

@@ -0,0 +1 @@
+(conditional_construct) @fold

runtime/queries/readline/highlights.scm

@@ -0,0 +1,69 @@
+(comment) @comment @spell
+
+"set" @keyword
+
+[
+  "$if"
+  "$else"
+  "$endif"
+] @keyword.conditional
+
+"$include" @keyword.import
+
+[
+  "="
+  "=="
+  "!="
+  ">="
+  "<="
+  ">"
+  "<"
+] @operator
+
+[
+  ":"
+  "-"
+] @punctuation.delimiter
+
+[
+  (application_name)
+  (keyname)
+  (keyseq)
+  (macro)
+  (string_value)
+  (term_name)
+] @string
+
+(file_path) @string.special.path
+
+(escape_sequence) @string.escape
+
+(symbolic_character_name) @character.special
+
+(key_literal) @character
+
+(function_name) @function
+
+[
+  (bell_variable)
+  (bool_variable)
+  (edit_mode_variable)
+  (keymap_variable)
+  (number_variable)
+  (string_variable)
+] @variable.builtin
+
+[
+  (bell_value)
+  (edit_mode_value)
+  (keymap_value)
+  "version"
+  "term"
+  "mode"
+] @constant.builtin
+
+(number_value) @number
+
+(version_number) @number.float
+
+(bool_value) @boolean

runtime/queries/readline/indents.scm

@@ -0,0 +1,11 @@
+(conditional_construct) @indent.begin
+
+(ERROR
+  "$if") @indent.begin
+
+[
+  "$else"
+  "$endif"
+] @indent.branch
+
+"$endif" @indent.end

runtime/queries/readline/injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))