feat!: drop modules, general refactor and cleanup

runtime/queries/proto/folds.scm

@@ -0,0 +1,5 @@
+[
+  (enum)
+  (message)
+  (service)
+] @fold

runtime/queries/proto/highlights.scm

@@ -0,0 +1,82 @@
+[
+  "extend"
+  "extensions"
+  "oneof"
+  "option"
+  "reserved"
+  "syntax"
+  "to"
+] @keyword
+
+[
+  "enum"
+  "service"
+  "message"
+] @keyword.type
+
+"rpc" @keyword.function
+
+"returns" @keyword.return
+
+[
+  "optional"
+  "repeated"
+  "required"
+] @keyword.modifier
+
+[
+  "package"
+  "import"
+] @keyword.import
+
+[
+  (key_type)
+  (type)
+  (message_name)
+  (enum_name)
+  (service_name)
+  (rpc_name)
+  (message_or_enum_type)
+] @type
+
+(enum_field
+  (identifier) @constant)
+
+(string) @string
+
+[
+  "\"proto3\""
+  "\"proto2\""
+] @string.special
+
+(int_lit) @number
+
+(float_lit) @number.float
+
+[
+  (true)
+  (false)
+] @boolean
+
+(comment) @comment @spell
+
+((comment) @comment.documentation
+  (#lua-match? @comment.documentation "^/[*][*][^*].*[*]/$"))
+
+[
+  "("
+  ")"
+  "["
+  "]"
+  "{"
+  "}"
+  "<"
+  ">"
+] @punctuation.bracket
+
+[
+  ";"
+  ","
+] @punctuation.delimiter
+
+"=" @operator

runtime/queries/proto/indents.scm

@@ -0,0 +1,11 @@
+[
+  (message_body)
+  (enum_body)
+] @indent.begin
+
+"}" @indent.end @indent.branch
+
+[
+  (ERROR)
+  (comment)
+] @indent.auto

runtime/queries/proto/injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))