feat!: drop modules, general refactor and cleanup

runtime/queries/pioasm/highlights.scm

@@ -0,0 +1,93 @@
+[
+  (line_comment)
+  (block_comment)
+] @comment @spell
+
+(label_decl) @label
+
+(string) @string
+
+(instruction
+  opcode: _ @function.call)
+
+[
+  "pins"
+  "x"
+  "y"
+  "null"
+  "isr"
+  "osr"
+  "osre"
+  "status"
+  "pc"
+  "exec"
+] @constant.builtin
+
+(wait_source
+  [
+    "irq"
+    "gpio"
+    "pin"
+  ] @constant.builtin)
+
+(out_target
+  "pindirs" @constant.builtin)
+
+(set_target
+  "pindirs" @constant.builtin)
+
+(directive
+  "pindirs" @attribute)
+
+(condition
+  [
+    "--"
+    "!="
+  ] @operator)
+
+(expression
+  [
+    "+"
+    "-"
+    "*"
+    "/"
+    "|"
+    "&"
+    "^"
+    "::"
+  ] @operator)
+
+(not) @operator
+
+[
+  (optional)
+  (irq_modifiers)
+] @keyword.modifier
+
+[
+  "block"
+  "noblock"
+  "rel"
+] @attribute
+
+[
+  "iffull"
+  "ifempty"
+] @keyword.conditional
+
+"public" @keyword.modifier
+
+(integer) @number
+
+(directive
+  (identifier) @variable)
+
+(directive
+  (symbol_def
+    (identifier) @variable))
+
+(value
+  (identifier) @variable)
+
+(directive
+  directive: _ @keyword.directive)

runtime/queries/pioasm/injections.scm

@@ -0,0 +1,15 @@
+([
+  (line_comment)
+  (block_comment)
+] @injection.content
+  (#set! injection.language "comment"))
+
+((code_block
+  (code_block_language) @_language
+  (code_block_body) @injection.content)
+  (#eq? @_language "c-sdk")
+  (#set! injection.language "c"))
+
+(code_block
+  (code_block_language) @injection.language
+  (code_block_body) @injection.content)