feat!: drop modules, general refactor and cleanup

runtime/queries/meson/folds.scm

@@ -0,0 +1,9 @@
+[
+  (normal_command)
+  (if_condition)
+  (if_command)
+  (else_command)
+  (elseif_command)
+  (foreach_command)
+  (list)
+] @fold

runtime/queries/meson/highlights.scm

@@ -0,0 +1,77 @@
+(comment) @comment @spell
+
+(number) @number
+
+(bool) @boolean
+
+(identifier) @variable
+
+[
+  "("
+  ")"
+  "{"
+  "}"
+  "["
+  "]"
+] @punctuation.bracket
+
+[
+  ":"
+  ","
+  "."
+] @punctuation.delimiter
+
+[
+  "and"
+  "not"
+  "or"
+  "in"
+] @keyword.operator
+
+[
+  "="
+  "=="
+  "!="
+  "+"
+  "/"
+  "/="
+  "+="
+  "-="
+  ">"
+  ">="
+] @operator
+
+(ternaryoperator
+  [
+    "?"
+    ":"
+  ] @keyword.conditional.ternary)
+
+[
+  "if"
+  "elif"
+  "else"
+  "endif"
+] @keyword.conditional
+
+[
+  "foreach"
+  "endforeach"
+  (keyword_break)
+  (keyword_continue)
+] @keyword.repeat
+
+(string) @string
+
+"@" @punctuation.special
+
+(normal_command
+  command: (identifier) @function)
+
+(pair
+  key: (identifier) @property)
+
+(escape_sequence) @string.escape
+
+((identifier) @variable.builtin
+  (#any-of? @variable.builtin "meson" "host_machine" "build_machine" "target_machine"))

runtime/queries/meson/indents.scm

@@ -0,0 +1,25 @@
+[
+  (list)
+  (dictionaries)
+  (normal_command)
+  (if_condition)
+  (foreach_command)
+  (ternaryoperator)
+  (ERROR
+    "?") ; support partial ternary
+] @indent.begin
+
+[
+  ")"
+  "]"
+  "}"
+  (elseif_command)
+  (else_command)
+  "endif"
+  "endforeach"
+] @indent.branch @indent.end
+
+(expression_statement
+  object: (_)) @indent.begin
+
+(comment) @indent.auto

runtime/queries/meson/injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))