feat!: drop modules, general refactor and cleanup

runtime/queries/menhir/highlights.scm

@@ -0,0 +1,73 @@
+[
+  "%parameter"
+  "%token"
+  "%type"
+  "%start"
+  "%attribute"
+  "%left"
+  "%right"
+  "%nonassoc"
+  "%public"
+  "%inline"
+  "%prec"
+] @keyword
+
+"%on_error_reduce" @keyword.exception
+
+"let" @keyword.function
+
+[
+  (equality_symbol)
+  ":"
+  "|"
+  ";"
+  ","
+] @punctuation.delimiter
+
+[
+  "="
+  "~"
+] @operator
+
+(modifier) @operator
+
+"_" @character.special
+
+[
+  "<"
+  ">"
+  "{"
+  "}"
+  "%{"
+  "%}"
+  "%%"
+] @punctuation.special
+
+[
+  "("
+  ")"
+] @punctuation.bracket
+
+(old_rule
+  (symbol) @function)
+
+(new_rule
+  (lid) @function)
+
+(precedence
+  (symbol) @variable.parameter)
+
+(funcall) @function.call
+
+; Not very accurant but does a decent job
+(uid) @constant
+
+(ocaml_type) @type
+
+(ocaml) @none
+
+[
+  (comment)
+  (line_comment)
+  (ocaml_comment)
+] @comment @spell

runtime/queries/menhir/injections.scm

@@ -0,0 +1,9 @@
+([
+  (comment)
+  (line_comment)
+  (ocaml_comment)
+] @injection.content
+  (#set! injection.language "comment"))
+
+((ocaml) @injection.content
+  (#set! injection.language "ocaml"))