feat!: drop modules, general refactor and cleanup

runtime/queries/m68k/folds.scm

@@ -0,0 +1 @@
+(element_list) @fold

runtime/queries/m68k/highlights.scm

@@ -0,0 +1,81 @@
+(symbol) @variable
+
+(label
+  name: (symbol) @label)
+
+[
+  (instruction_mnemonic)
+  (directive_mnemonic)
+] @function.builtin
+
+(include
+  (directive_mnemonic) @keyword.import)
+
+(include_bin
+  (directive_mnemonic) @keyword.import)
+
+(include_dir
+  (directive_mnemonic) @keyword.import)
+
+(size) @attribute
+
+(macro_definition
+  name: (symbol) @function.macro)
+
+(macro_call
+  name: (symbol) @function.macro)
+
+(string_literal) @string
+
+(path) @string.special.path
+
+[
+  (decimal_literal)
+  (hexadecimal_literal)
+  (octal_literal)
+  (binary_literal)
+] @number
+
+[
+  (reptn)
+  (carg)
+  (narg)
+  (macro_arg)
+] @variable.builtin
+
+[
+  (control_mnemonic)
+  (address_register)
+  (data_register)
+  (float_register)
+  (named_register)
+] @keyword
+
+(repeat
+  (control_mnemonic) @keyword.repeat)
+
+(conditional
+  (control_mnemonic) @keyword.conditional)
+
+(comment) @comment @spell
+
+[
+  (operator)
+  "="
+  "#"
+] @operator
+
+[
+  "."
+  ","
+  "/"
+  "-"
+] @punctuation.delimiter
+
+[
+  "("
+  ")"
+  ")+"
+] @punctuation.bracket
+
+(section) @module

runtime/queries/m68k/injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))

runtime/queries/m68k/locals.scm

@@ -0,0 +1,26 @@
+(macro_definition
+  name: (symbol) @local.definition.macro)
+
+(symbol_assignment
+  name: (symbol) @local.definition.var)
+
+(label
+  name: (symbol) @local.definition.constant)
+
+(symbol_definition
+  name: (symbol) @local.definition.constant)
+
+(offset_definition
+  name: (symbol) @local.definition.constant)
+
+(register_definition
+  name: (symbol) @local.definition.constant)
+
+(register_list_definition
+  name: (symbol) @local.definition.constant)
+
+(external_reference
+  symbols: (symbol_list
+    (symbol) @local.definition.import))
+
+(symbol) @local.reference