feat!: drop modules, general refactor and cleanup

runtime/queries/kdl/folds.scm

@@ -0,0 +1,7 @@
+; Folds
+[
+  (node)
+  (node_children)
+  (string)
+  (multi_line_comment)
+] @fold

runtime/queries/kdl/highlights.scm

@@ -0,0 +1,71 @@
+; Types
+; Variables
+(identifier) @variable
+
+; Nodes
+(node
+  (identifier) @tag)
+
+; Type annotation
+(type
+  (identifier) @type)
+
+; Properties
+(prop
+  (identifier) @property)
+
+; Operators
+[
+  "="
+  "+"
+  "-"
+] @operator
+
+; Literals
+(string) @string
+
+(escape) @string.escape
+
+(number) @number
+
+(number
+  (decimal) @number.float)
+
+(number
+  (exponent) @number.float)
+
+(boolean) @boolean
+
+"null" @constant.builtin
+
+; Punctuation
+[
+  "{"
+  "}"
+] @punctuation.bracket
+
+[
+  "("
+  ")"
+] @punctuation.bracket
+
+";" @punctuation.delimiter
+
+; Comments
+[
+  (single_line_comment)
+  (multi_line_comment)
+] @comment @spell
+
+(node
+  (node_comment)
+  (#set! priority 105)) @comment
+
+(node
+  (node_field
+    (node_field_comment)
+    (#set! priority 105)) @comment)
+
+(node_children
+  (node_children_comment)
+  (#set! priority 105)) @comment

runtime/queries/kdl/indents.scm

@@ -0,0 +1,14 @@
+(node
+  (node_children) @indent.begin)
+
+"}" @indent.end
+
+[
+  "{"
+  "}"
+] @indent.branch
+
+[
+  "("
+  ")"
+] @indent.branch

runtime/queries/kdl/injections.scm

@@ -0,0 +1,5 @@
+([
+  (single_line_comment)
+  (multi_line_comment)
+] @injection.content
+  (#set! injection.language "comment"))

runtime/queries/kdl/locals.scm

@@ -0,0 +1,16 @@
+(document) @local.scope
+
+(node
+  (node_children) @local.scope)
+
+(node_children
+  (node) @local.scope)
+
+(identifier) @local.reference
+
+(node_field) @local.definition.field
+
+(node
+  (identifier) @local.definition.type)
+
+(type) @local.definition.type