benbot/nvim-treesitter
1
0
Fork 0
mirror of https://github.com/nvim-treesitter/nvim-treesitter.git synced 2026-07-19 11:50:09 -04:00
Code Issues Projects Releases Packages Wiki Activity Actions 2

feat!: drop modules, general refactor and cleanup

Browse source
This commit is contained in:
Christian Clason 2023-06-12 09:54:30 -06:00
parent 310f0925ec
commit 692b051b09
1247 changed files with 6096 additions and 9074 deletions
Download patch file Download diff file Expand all files Collapse all files

30
runtime/queries/javadoc/injections.scm Normal file
View file

@ -0,0 +1,30 @@
; @value tags without double-quotes
((bare_format_string) @injection.content
(#set! injection.language "printf"))
; @value tags with double quotes
((literal_format_string) @injection.content
(#offset! @injection.content 0 1 0 -1)
(#set! injection.language "printf"))
; injected code snippets
((snippet_tag
(attributes
(attribute
name: (identifier) @_attribute_key
value: (attribute_value
[
(identifier) @injection.language
(string_literal
(quoted_value) @injection.language)
])))
body: (description) @injection.content)
(#eq? @_attribute_key "lang"))
; html content
((description) @injection.content
(#set! injection.language "html"))
; markdown content
((markdown_description) @injection.content
(#set! injection.language "markdown_inline"))