feat!: drop modules, general refactor and cleanup

runtime/queries/hyprlang/folds.scm

@@ -0,0 +1 @@
+(section) @fold

runtime/queries/hyprlang/highlights.scm

@@ -0,0 +1,65 @@
+(comment) @comment @spell
+
+[
+  "source"
+  "exec"
+  "exec-once"
+] @keyword
+
+(keyword
+  (name) @keyword)
+
+(assignment
+  (name) @property)
+
+(section
+  (name) @module)
+
+(section
+  device: (device_name) @string.special)
+
+(variable) @variable
+
+"$" @punctuation.special
+
+(boolean) @boolean
+
+[
+  "deg"
+  (string)
+  (string_literal)
+] @string
+
+(mod) @constant.builtin
+
+[
+  "rgb"
+  "rgba"
+] @function.builtin
+
+[
+  (number)
+  (legacy_hex)
+  (angle)
+  (hex)
+] @number
+
+[
+  ","
+  ":"
+  "x"
+  "@"
+] @punctuation.delimiter
+
+[
+  "("
+  ")"
+  "{"
+  "}"
+] @punctuation.bracket
+
+[
+  "="
+  "-"
+  "+"
+] @operator

runtime/queries/hyprlang/indents.scm

@@ -0,0 +1,6 @@
+(section) @indent.begin
+
+(section
+  "}" @indent.end)
+
+"}" @indent.branch

runtime/queries/hyprlang/injections.scm

@@ -0,0 +1,31 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))
+
+(exec
+  (string) @injection.content
+  (#set! injection.language "bash"))
+
+((keyword
+  (name) @_bind
+  (params
+    .
+    (_)
+    .
+    (_)
+    .
+    (_)?
+    .
+    (string) @_exec
+    .
+    (string) @injection.content))
+  (#lua-match? @_bind "^bind")
+  (#lua-match? @_exec "^%s*exec%s*$")
+  (#set! injection.language "bash"))
+
+((assignment
+  (name) @_name
+  (string) @injection.content)
+  (#any-of? @_name
+    "lock_cmd" "unlock_cmd" "before_sleep_cmd" "after_sleep_cmd" "on-timeout" "on-resume"
+    "reload_cmd")
+  (#set! injection.language "bash"))