feat!: drop modules, general refactor and cleanup

runtime/queries/editorconfig/folds.scm

@@ -0,0 +1 @@
+(section) @fold

runtime/queries/editorconfig/highlights.scm

@@ -0,0 +1,55 @@
+(comment) @comment @spell
+
+(section
+  (section_name) @string.special.path)
+
+(character_choice
+  (character) @constant)
+
+(character_range
+  start: (character) @constant
+  end: (character) @constant)
+
+[
+  "["
+  "]"
+  "{"
+  "}"
+] @punctuation.bracket
+
+[
+  ","
+  ".."
+  (path_separator)
+] @punctuation.delimiter
+
+[
+  "-"
+  "="
+  (negation)
+] @operator
+
+[
+  (wildcard_characters)
+  (wildcard_any_characters)
+  (wildcard_single_character)
+] @character.special
+
+(escaped_character) @string.escape
+
+(pair
+  key: (identifier) @property
+  value: (_) @string)
+
+(boolean) @boolean
+
+(integer) @number
+
+(unset) @constant.builtin
+
+[
+  (spelling_language)
+  (indent_style)
+  (end_of_line)
+  (charset)
+] @string.special

runtime/queries/editorconfig/injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))