feat!: drop modules, general refactor and cleanup

runtime/queries/doxygen/highlights.scm

@@ -0,0 +1,61 @@
+((tag_name) @keyword
+  (#set! priority 105))
+
+[
+  "@code"
+  "@endcode"
+] @keyword
+
+(identifier) @variable
+
+((tag
+  (tag_name) @_param
+  (identifier) @variable.parameter)
+  (#any-of? @_param "@param" "\\param"))
+
+(function
+  (identifier) @function)
+
+(function_link) @function
+
+(emphasis) @markup.italic
+
+[
+  "\\a"
+  "\\c"
+] @tag
+
+(code_block_language) @label
+
+[
+  "in"
+  "out"
+  "inout"
+] @keyword.modifier
+
+"~" @operator
+
+[
+  "<a"
+  ">"
+  "</a>"
+] @tag
+
+[
+  "."
+  ","
+  "::"
+  (code_block_start)
+  (code_block_end)
+] @punctuation.delimiter
+
+[
+  "("
+  ")"
+  "{"
+  "}"
+  "["
+  "]"
+] @punctuation.bracket
+
+(code_block_content) @none

runtime/queries/doxygen/indents.scm

@@ -0,0 +1 @@
+(document) @indent.auto

runtime/queries/doxygen/injections.scm

@@ -0,0 +1,15 @@
+((type) @injection.content
+  (#set! injection.parent))
+
+([
+  (function_link)
+  (code)
+] @injection.content
+  (#set! injection.parent))
+
+((link) @injection.content
+  (#set! injection.language "html"))
+
+(code_block
+  (code_block_language) @injection.language
+  (code_block_content) @injection.content)