feat!: drop modules, general refactor and cleanup

runtime/queries/dot/highlights.scm

@@ -0,0 +1,49 @@
+(identifier) @type
+
+[
+  "strict"
+  "graph"
+  "digraph"
+  "subgraph"
+  "node"
+  "edge"
+] @keyword
+
+(string_literal) @string
+
+(number_literal) @number
+
+[
+  (edgeop)
+  (operator)
+] @operator
+
+[
+  ","
+  ";"
+] @punctuation.delimiter
+
+[
+  "{"
+  "}"
+  "["
+  "]"
+  "<"
+  ">"
+] @punctuation.bracket
+
+(subgraph
+  id: (id
+    (identifier) @module))
+
+(attribute
+  name: (id
+    (identifier) @variable.member))
+
+(attribute
+  value: (id
+    (identifier) @constant))
+
+(comment) @comment @spell
+
+(preproc) @keyword.directive

runtime/queries/dot/indents.scm

@@ -0,0 +1,9 @@
+[
+  (block)
+  (attr_list)
+] @indent.begin
+
+[
+  "}"
+  "]"
+] @indent.branch @indent.end

runtime/queries/dot/injections.scm

@@ -0,0 +1,5 @@
+((html_internal) @injection.content
+  (#set! injection.language "html"))
+
+((comment) @injection.content
+  (#set! injection.language "comment"))