feat: editorconfig parser and queries

lockfile.json

@@ -140,6 +140,9 @@
   "ebnf": {
     "revision": "8e635b0b723c620774dfb8abf382a7f531894b40"
   },
+  "editorconfig": {
+    "revision": "aec8400b9554eae784125054ac4af7b767804844"
+  },
   "eds": {
     "revision": "0ad62cb635c2f4353359a88dec9e3a57bbf9f66d"
   },

lua/nvim-treesitter/parsers.lua

@@ -469,6 +469,14 @@ list.ebnf = {
   experimental = true,
 }
 
+list.editorconfig = {
+  install_info = {
+    url = "https://github.com/ValdezFOmar/tree-sitter-editorconfig",
+    files = { "src/parser.c", "src/scanner.c" },
+  },
+  maintainers = { "@ValdezFOmar" },
+}
+
 list.eds = {
   install_info = {
     url = "https://github.com/uyha/tree-sitter-eds",

queries/editorconfig/folds.scm

@@ -0,0 +1 @@
+(section) @fold

queries/editorconfig/highlights.scm

@@ -0,0 +1,56 @@
+(comment) @comment @spell
+
+; consistency with toml and ini
+(section
+  (section_name) @type)
+
+(character_choice
+  (character) @constant)
+
+(character_range
+  start: (character) @constant
+  end: (character) @constant)
+
+[
+  "["
+  "]"
+  "{"
+  "}"
+] @punctuation.bracket
+
+[
+  ","
+  ".."
+  (path_separator)
+] @punctuation.delimiter
+
+[
+  "-"
+  "="
+  (negation)
+] @operator
+
+[
+  (wildcard_characters)
+  (wildcard_any_characters)
+  (wildcard_single_character)
+] @character.special
+
+(escaped_character) @string.escape
+
+(pair
+  key: (identifier) @property
+  value: (_) @string)
+
+(boolean) @boolean
+
+(integer) @number
+
+(unset) @constant.builtin
+
+[
+  (spelling_language)
+  (indent_style)
+  (end_of_line)
+  (charset)
+] @string.special

queries/editorconfig/injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))