feat!: drop modules, general refactor and cleanup

runtime/queries/yang/folds.scm

@@ -0,0 +1,3 @@
+[
+ (block)
+] @fold

runtime/queries/yang/highlights.scm

@@ -0,0 +1,43 @@
+
+(comment) @comment
+
+; Module / submodule
+["module" "submodule"] @keyword
+
+; Keywords
+(statement_keyword) @keyword
+(statement_keyword "import") @include
+(extension_keyword) @function
+
+; Arguments
+(built_in_type) @type.builtin
+(number) @number
+(boolean) @boolean
+(date) @number
+(range (_ ".." @punctuation.special))
+(range (_ "|" @punctuation.special))
+(quoted_range "\"" @string.special)
+(quoted_range "'" @string.special)
+(yang_version) @constant.builtin
+(identifier) @variable
+(node_identifier) @variable
+(string) @string
+(string (escape_sequence) @string.escape)
+(unquoted_string) @string
+(keypath) @string.special
+
+; Always highlight the value of an enum statement as a string
+(enum_value) @string
+
+; Highlight xpath and pattern strings differently from plain strings
+(statement
+  (statement_keyword "must")
+  (argument (string) @string.special))
+(statement
+  (statement_keyword "pattern")
+  (argument (string) @string.regex))
+
+; Punctuation
+(plus_symbol) @operator
+["{" "}"] @punctuation.bracket
+[";"] @punctuation.delimiter

runtime/queries/yang/indents.scm

@@ -0,0 +1,11 @@
+(module) @indent.begin
+(submodule) @indent.begin
+(statement) @indent.begin
+(extension_statement) @indent.begin
+(statement ";" @indent.end)
+(extension_statement ";" @indent.end)
+(block "}" @indent.end @indent.branch)
+
+((string) @indent.align
+ (#set! indent.open_delimiter "\"")
+ (#set! indent.close_delimiter "\""))

runtime/queries/yang/injections.scm

@@ -0,0 +1,8 @@
+((comment) @injection.content
+ (#set! injection.language "comment"))
+
+((statement
+  (statement_keyword "pattern")
+  (argument (string) @injection.content))
+ (#set! injection.language "regex")
+ (#offset! @injection.content 0 1 0 -1))