feat!: drop modules, general refactor and cleanup

runtime/queries/yaml/folds.scm

@@ -0,0 +1,4 @@
+[
+  (block_mapping_pair)
+  (block_sequence_item)
+] @fold

runtime/queries/yaml/highlights.scm

@@ -0,0 +1,53 @@
+(boolean_scalar) @boolean
+(null_scalar) @constant.builtin
+(double_quote_scalar) @string
+(single_quote_scalar) @string
+((block_scalar) @string (#set! "priority" 99))
+(string_scalar) @string
+(escape_sequence) @string.escape
+(integer_scalar) @number
+(float_scalar) @number
+(comment) @comment @spell
+(anchor_name) @type
+(alias_name) @type
+(tag) @type
+(ERROR) @error
+
+[
+  (yaml_directive)
+  (tag_directive)
+  (reserved_directive)
+] @preproc
+
+(block_mapping_pair
+  key: (flow_node [(double_quote_scalar) (single_quote_scalar)] @field))
+(block_mapping_pair
+  key: (flow_node (plain_scalar (string_scalar) @field)))
+
+(flow_mapping
+  (_ key: (flow_node [(double_quote_scalar) (single_quote_scalar)] @field)))
+(flow_mapping
+  (_ key: (flow_node (plain_scalar (string_scalar) @field))))
+
+[
+ ","
+ "-"
+ ":"
+ ">"
+ "?"
+ "|"
+] @punctuation.delimiter
+
+[
+ "["
+ "]"
+ "{"
+ "}"
+] @punctuation.bracket
+
+[
+ "*"
+ "&"
+ "---"
+ "..."
+] @punctuation.special

runtime/queries/yaml/indents.scm

@@ -0,0 +1,6 @@
+[
+  (block_mapping_pair value: (block_node))
+  (block_sequence_item)
+] @indent.begin
+
+(ERROR) @indent.auto

runtime/queries/yaml/injections.scm

@@ -0,0 +1,72 @@
+((comment) @injection.content
+ (#set! injection.language "comment"))
+
+;; Github actions ("run") / Gitlab CI ("scripts")
+(block_mapping_pair
+  key: (flow_node) @_run (#any-of? @_run "run" "script" "before_script" "after_script")
+  value: (flow_node
+           (plain_scalar
+             (string_scalar) @injection.content)
+           (#set! injection.language "bash")))
+
+(block_mapping_pair
+  key: (flow_node) @_run (#any-of? @_run "run" "script" "before_script" "after_script")
+  value: (block_node
+           (block_scalar) @injection.content
+           (#set! injection.language "bash")
+           (#offset! @injection.content 0 1 0 0)))
+
+(block_mapping_pair
+  key: (flow_node) @_run (#any-of? @_run "run" "script" "before_script" "after_script")
+  value: (block_node
+           (block_sequence
+             (block_sequence_item
+                (flow_node
+                  (plain_scalar
+                    (string_scalar) @injection.content))
+                (#set! injection.language "bash")))))
+
+(block_mapping_pair
+  key: (flow_node) @_run (#any-of? @_run "script" "before_script" "after_script")
+  value: (block_node
+           (block_sequence
+             (block_sequence_item
+               (block_node
+                  (block_scalar) @injection.content
+                  (#set! injection.language "bash")
+                  (#offset! @injection.content 0 1 0 0))))))
+
+;; Prometheus Alertmanager ("expr")
+(block_mapping_pair
+  key: (flow_node) @_expr (#eq? @_expr "expr")
+  value: (flow_node
+           (plain_scalar
+             (string_scalar) @injection.content)
+           (#set! injection.language "promql")))
+
+(block_mapping_pair
+  key: (flow_node) @_expr (#eq? @_expr "expr")
+  value: (block_node
+           (block_scalar) @injection.content
+           (#set! injection.language "promql")
+           (#offset! @injection.content 0 2 0 0)))
+
+(block_mapping_pair
+  key: (flow_node) @_expr (#eq? @_expr "expr")
+  value: (block_node
+           (block_sequence
+             (block_sequence_item
+               (flow_node
+                 (plain_scalar
+                   (string_scalar) @injection.content))
+               (#set! injection.language "promql")))))
+
+(block_mapping_pair
+  key: (flow_node) @_expr (#eq? @_expr "expr")
+  value: (block_node
+           (block_sequence
+             (block_sequence_item
+               (block_node
+                  (block_scalar) @injection.content
+                  (#set! injection.language "promql")
+                  (#offset! @injection.content 0 2 0 0))))))

runtime/queries/yaml/locals.scm

@@ -0,0 +1,8 @@
+[
+ (stream)
+ (document)
+ (block_node)
+] @scope
+
+(anchor_name) @definition
+(alias_name) @reference