benbot/nvim-treesitter
1
0
Fork 0
mirror of https://github.com/nvim-treesitter/nvim-treesitter.git synced 2026-07-20 04:10:06 -04:00
Code Issues Projects Releases Packages Wiki Activity Actions 2

feat!: drop modules, general refactor and cleanup

Browse source
This commit is contained in:
Christian Clason 2023-06-12 09:54:30 -06:00
parent c13e28f894
commit 2c8f2f2fad
829 changed files with 4905 additions and 8010 deletions
Download patch file Download diff file Expand all files Collapse all files

80
runtime/queries/vue/injections.scm Normal file
View file

@ -0,0 +1,80 @@
; inherits html_tags
; <script lang="css">
((style_element
(start_tag
(attribute
(attribute_name) @_lang
(quoted_attribute_value (attribute_value) @injection.language)))
(raw_text) @injection.content)
(#eq? @_lang "lang")
(#any-of? @injection.language "css" "scss")
(#set! injection.include-children))
; TODO: When nvim-treesitter has postcss and less parsers, use @injection.language and @injection.content instead
; <script lang="scss">
((style_element
(start_tag
(attribute
(attribute_name) @_lang
(quoted_attribute_value (attribute_value) @_scss)))
(raw_text) @injection.content
(#eq? @_lang "lang")
(#any-of? @_scss "less" "postcss")
(#set! injection.language "scss")
(#set! injection.include-children)))
; <script lang="js">
((script_element
(start_tag
(attribute
(attribute_name) @_lang
(quoted_attribute_value (attribute_value) @_js)))
(raw_text) @injection.content)
(#eq? @_lang "lang")
(#eq? @_js "js")
(#set! injection.language "javascript")
(#set! injection.include-children))
; <script lang="ts">
((script_element
(start_tag
(attribute
(attribute_name) @_lang
(quoted_attribute_value (attribute_value) @_ts)))
(raw_text) @injection.content)
(#eq? @_lang "lang")
(#eq? @_ts "ts")
(#set! injection.language "typescript")
(#set! injection.include-children))
; <script lang="tsx">
; <script lang="jsx">
((script_element
(start_tag
(attribute
(attribute_name) @_attr
(quoted_attribute_value (attribute_value) @injection.language)))
(#eq? @_attr "lang")
(#any-of? @injection.language "tsx" "jsx")
(raw_text) @injection.content)
(#set! injection.include-children))
((interpolation
(raw_text) @injection.content)
(#set! injection.language "javascript")
(#set! injection.include-children))
(directive_attribute
(quoted_attribute_value
(attribute_value) @injection.content
(#set! injection.language "javascript")
(#set! injection.include-children)))
(template_element
(start_tag
(attribute
(quoted_attribute_value (attribute_value) @injection.language)))
(text) @injection.content
(#eq? @injection.language "pug")
(#set! injection.include-children))