feat!: drop modules, general refactor and cleanup

runtime/queries/ron/folds.scm

@@ -0,0 +1,7 @@
+[
+  (array)
+  (map)
+  (tuple)
+  (struct)
+  (block_comment)
+] @fold

runtime/queries/ron/highlights.scm

@@ -0,0 +1,53 @@
+; Structs
+;------------
+
+(enum_variant) @constant
+(struct_entry (identifier) @property)
+(struct_entry (enum_variant (identifier) @constant))
+(struct_name (identifier)) @type
+
+(unit_struct) @type.builtin
+
+
+; Literals
+;------------
+
+(string) @string
+(boolean) @boolean
+(integer) @number
+(float) @float
+(char) @character
+
+
+; Comments
+;------------
+
+[
+  (line_comment)
+  (block_comment)
+] @comment @spell
+
+
+; Punctuation
+;------------
+
+["{" "}"] @punctuation.bracket
+
+["(" ")"] @punctuation.bracket
+
+["[" "]"] @punctuation.bracket
+
+[
+  ","
+  ":"
+] @punctuation.delimiter
+
+[
+  "-"
+] @operator
+
+; Special
+;------------
+
+(escape_sequence) @string.escape
+(ERROR) @error

runtime/queries/ron/indents.scm

@@ -0,0 +1,12 @@
+[
+  (array)
+  (map)
+  (tuple)
+  (struct)
+] @indent.begin
+
+[ "{" "}" ] @indent.branch
+
+[ "(" ")" ] @indent.branch
+
+[ "[" "]" ] @indent.branch

runtime/queries/ron/injections.scm

@@ -0,0 +1,5 @@
+([
+  (line_comment)
+  (block_comment)
+] @injection.content
+ (#set! injection.language "comment"))

runtime/queries/ron/locals.scm

@@ -0,0 +1,12 @@
+(source_file) @scope
+(source_file (array) @scope)
+(source_file (map) @scope)
+(source_file (struct) @scope)
+(source_file (tuple) @scope)
+
+(identifier) @reference
+
+(struct_entry (identifier) @definition.field)
+(struct_entry (identifier) @definition.enum (enum_variant))
+
+(struct (struct_name) @definition.type)