feat!: drop modules, general refactor and cleanup

runtime/queries/query/folds.scm

@@ -0,0 +1,6 @@
+[
+  (named_node)
+  (predicate)
+  (grouping)
+  (list)
+] @fold

runtime/queries/query/highlights.scm

@@ -0,0 +1,34 @@
+(string) @string
+(escape_sequence) @string.escape
+(capture (identifier) @type)
+(anonymous_node (identifier) @string)
+(predicate name: (identifier) @function)
+(named_node name: (identifier) @variable)
+(field_definition name: (identifier) @property)
+(negated_field "!" @operator (identifier) @property)
+(comment) @comment @spell
+
+(quantifier) @operator
+(predicate_type) @punctuation.special
+
+"." @operator
+
+[
+  "["
+  "]"
+  "("
+  ")"
+] @punctuation.bracket
+
+":" @punctuation.delimiter
+["@" "#"] @punctuation.special
+"_" @constant
+
+((parameters (identifier) @number)
+ (#match? @number "^[-+]?[0-9]+(.[0-9]+)?$"))
+
+((program . (comment)* . (comment) @include)
+ (#lua-match? @include "^;+ *inherits *:"))
+
+((program . (comment)* . (comment) @preproc)
+ (#lua-match? @preproc "^;+ *extends"))

runtime/queries/query/indents.scm

@@ -0,0 +1,12 @@
+[
+  (list)
+] @indent.begin
+
+[
+  "["
+  "]"
+] @indent.begin
+
+[
+  "]"
+] @indent.branch

runtime/queries/query/injections.scm

@@ -0,0 +1,23 @@
+((predicate 
+  name: (identifier) @_name
+  parameters: (parameters (string) @injection.content))
+ (#any-of? @_name "match" "not-match" "vim-match" "not-vim-match")
+ (#set! injection.language "regex")
+ (#offset! @injection.content 0 1 0 -1))
+
+((predicate
+  name: (identifier) @_name
+  parameters: (parameters (string) @injection.content))
+ (#any-of? @_name "lua-match" "not-lua-match")
+ (#set! injection.language "luap")
+ (#offset! @injection.content 0 1 0 -1))
+
+((predicate
+   name: (identifier) @_name
+   parameters: (parameters (string) @injection.content . (string) .))
+ (#any-of? @_name "gsub" "not-gsub")
+ (#set! injection.language "luap")
+ (#offset! @injection.content 0 1 0 -1))
+
+((comment) @injection.content
+ (#set! injection.language "comment"))

runtime/queries/query/locals.scm

@@ -0,0 +1,15 @@
+(program) @scope
+(program (named_node) @scope)
+(program (anonymous_node) @scope)
+(program (grouping) @scope)
+
+(identifier) @reference
+
+(named_node
+  (capture) @definition.var)
+
+(anonymous_node
+  (capture) @definition.var)
+
+(grouping
+  (capture) @definition.var)