benbot/nvim-treesitter
1
0
Fork 0
mirror of https://github.com/nvim-treesitter/nvim-treesitter.git synced 2026-07-05 13:00:08 -04:00
Code Issues Projects Releases Packages Wiki Activity Actions

feat!: drop modules, general refactor and cleanup

Browse source
This commit is contained in:
Christian Clason 2023-06-12 09:54:30 -06:00
parent c13e28f894
commit 2c8f2f2fad
829 changed files with 4905 additions and 8010 deletions
Download patch file Download diff file Expand all files Collapse all files

46
runtime/queries/php/injections.scm Normal file
View file

@ -0,0 +1,46 @@
((text) @injection.content
(#set! injection.language "html")
(#set! injection.combined))
((comment) @injection.content
(#set! injection.language "phpdoc"))
((heredoc
(heredoc_body) @injection.content
(heredoc_end) @injection.language
(#set! injection.include-children)
(#downcase! @injection.language)))
((nowdoc
(nowdoc_body) @injection.content
(heredoc_end) @injection.language
(#set! injection.include-children)
(#downcase! @injection.language)))
;; regex
((function_call_expression
function: (_) @_preg_func_identifier
arguments:
(arguments .
(argument
(_ (string_value) @injection.content))))
(#set! injection.language "regex")
(#lua-match? @_preg_func_identifier "^preg_"))
;; bash
((function_call_expression
function: (_) @_shell_func_identifier
arguments:
(arguments .
(argument
(_ (string_value) @injection.content))))
(#set! injection.language "bash")
(#any-of? @_shell_func_identifier "shell_exec" "escapeshellarg"
"escapeshellcmd" "exec" "passthru" "proc_open" "shell_exec" "system"))
(expression_statement
(shell_command_expression
(string_value) @injection.content)
(#set! injection.language "bash"))