feat!: drop modules, general refactor and cleanup

runtime/queries/lua/folds.scm

@@ -0,0 +1,10 @@
+[
+ (do_statement)
+ (while_statement)
+ (repeat_statement)
+ (if_statement)
+ (for_statement)
+ (function_declaration)
+ (function_definition)
+ (table_constructor)
+] @fold

runtime/queries/lua/highlights.scm

@@ -0,0 +1,250 @@
+;; Keywords
+
+"return" @keyword.return
+
+[
+ "goto"
+ "in"
+ "local"
+] @keyword
+
+(break_statement) @keyword
+
+(do_statement
+[
+  "do"
+  "end"
+] @keyword)
+
+(while_statement
+[
+  "while"
+  "do"
+  "end"
+] @repeat)
+
+(repeat_statement
+[
+  "repeat"
+  "until"
+] @repeat)
+
+(if_statement
+[
+  "if"
+  "elseif"
+  "else"
+  "then"
+  "end"
+] @conditional)
+
+(elseif_statement
+[
+  "elseif"
+  "then"
+  "end"
+] @conditional)
+
+(else_statement
+[
+  "else"
+  "end"
+] @conditional)
+
+(for_statement
+[
+  "for"
+  "do"
+  "end"
+] @repeat)
+
+(function_declaration
+[
+  "function"
+  "end"
+] @keyword.function)
+
+(function_definition
+[
+  "function"
+  "end"
+] @keyword.function)
+
+;; Operators
+
+[
+ "and"
+ "not"
+ "or"
+] @keyword.operator
+
+[
+  "+"
+  "-"
+  "*"
+  "/"
+  "%"
+  "^"
+  "#"
+  "=="
+  "~="
+  "<="
+  ">="
+  "<"
+  ">"
+  "="
+  "&"
+  "~"
+  "|"
+  "<<"
+  ">>"
+  "//"
+  ".."
+] @operator
+
+;; Punctuations
+
+[
+  ";"
+  ":"
+  "::"
+  ","
+  "."
+] @punctuation.delimiter
+
+;; Brackets
+
+[
+ "("
+ ")"
+ "["
+ "]"
+ "{"
+ "}"
+] @punctuation.bracket
+
+;; Variables
+
+(identifier) @variable
+
+((identifier) @constant.builtin
+  (#eq? @constant.builtin "_VERSION"))
+
+((identifier) @variable.builtin
+  (#eq? @variable.builtin "self"))
+
+((identifier) @namespace.builtin
+  (#any-of? @namespace.builtin "_G" "debug" "io" "jit" "math" "os" "package" "string" "table" "utf8"))
+
+((identifier) @keyword.coroutine
+  (#eq? @keyword.coroutine "coroutine"))
+
+(variable_list
+  (attribute
+    "<" @punctuation.bracket
+    (identifier) @attribute
+    ">" @punctuation.bracket))
+
+;; Labels
+
+(label_statement (identifier) @label)
+
+(goto_statement (identifier) @label)
+
+;; Constants
+
+((identifier) @constant
+ (#lua-match? @constant "^[A-Z][A-Z_0-9]*$"))
+
+(vararg_expression) @constant
+
+(nil) @constant.builtin
+
+[
+  (false)
+  (true)
+] @boolean
+
+;; Tables
+
+(field name: (identifier) @field)
+
+(dot_index_expression field: (identifier) @field)
+
+(table_constructor
+[
+  "{"
+  "}"
+] @constructor)
+
+;; Functions
+
+(parameters (identifier) @parameter)
+
+(function_declaration
+  name: [
+    (identifier) @function
+    (dot_index_expression
+      field: (identifier) @function)
+  ])
+
+(function_declaration
+  name: (method_index_expression
+    method: (identifier) @method))
+
+(assignment_statement
+  (variable_list .
+    name: [
+      (identifier) @function
+      (dot_index_expression
+        field: (identifier) @function)
+    ])
+  (expression_list .
+    value: (function_definition)))
+
+(table_constructor
+  (field
+    name: (identifier) @function
+    value: (function_definition)))
+
+(function_call
+  name: [
+    (identifier) @function.call
+    (dot_index_expression
+      field: (identifier) @function.call)
+    (method_index_expression
+      method: (identifier) @method.call)
+  ])
+
+(function_call
+  (identifier) @function.builtin
+  (#any-of? @function.builtin
+    ;; built-in functions in Lua 5.1
+    "assert" "collectgarbage" "dofile" "error" "getfenv" "getmetatable" "ipairs"
+    "load" "loadfile" "loadstring" "module" "next" "pairs" "pcall" "print"
+    "rawequal" "rawget" "rawlen" "rawset" "require" "select" "setfenv" "setmetatable"
+    "tonumber" "tostring" "type" "unpack" "xpcall"
+    "__add" "__band" "__bnot" "__bor" "__bxor" "__call" "__concat" "__div" "__eq" "__gc"
+    "__idiv" "__index" "__le" "__len" "__lt" "__metatable" "__mod" "__mul" "__name" "__newindex"
+    "__pairs" "__pow" "__shl" "__shr" "__sub" "__tostring" "__unm"))
+
+;; Others
+
+(comment) @comment @spell
+
+((comment) @comment.documentation
+  (#lua-match? @comment.documentation "^[-][-][-]"))
+
+((comment) @comment.documentation
+  (#lua-match? @comment.documentation "^[-][-](%s?)@"))
+
+(hash_bang_line) @preproc
+
+(number) @number
+
+(string) @string
+
+(escape_sequence) @string.escape
+
+;; Error
+(ERROR) @error

runtime/queries/lua/indents.scm

@@ -0,0 +1,43 @@
+[
+  (function_definition)
+  (function_declaration)
+  (field)
+  (do_statement)
+  (method_index_expression)
+  (while_statement)
+  (repeat_statement)
+  (if_statement)
+  "then"
+  (for_statement)
+  (return_statement)
+  (table_constructor)
+  (arguments)
+  (return_statement)
+] @indent.begin
+
+[
+  "end"
+  ")"
+  "}"
+] @indent.end
+
+(return_statement
+  (expression_list
+    (function_call))) @indent.dedent
+
+[
+  "end"
+  "then"
+  "until"
+  "}"
+  ")"
+  "elseif"
+  (elseif_statement)
+  "else"
+  (else_statement)
+] @indent.branch
+
+(comment) @indent.auto
+
+(string) @indent.auto
+

runtime/queries/lua/injections.scm

@@ -0,0 +1,92 @@
+((function_call
+  name: [
+    (identifier) @_cdef_identifier
+    (_ _ (identifier) @_cdef_identifier)
+  ]
+  arguments: 
+    (arguments 
+      (string content: _ @injection.content)))
+  (#set! injection.language "c")
+  (#eq? @_cdef_identifier "cdef"))
+
+((function_call
+  name: (_) @_vimcmd_identifier
+  arguments: (arguments (string content: _ @injection.content)))
+  (#set! injection.language "vim")
+  (#any-of? @_vimcmd_identifier "vim.cmd" "vim.api.nvim_command" "vim.api.nvim_command" "vim.api.nvim_exec2"))
+
+((function_call
+  name: (_) @_vimcmd_identifier
+  arguments: (arguments (string content: _ @injection.content) .))
+  (#set! injection.language "query")
+  (#any-of? @_vimcmd_identifier "vim.treesitter.query.set" "vim.treesitter.query.parse"))
+
+((function_call
+  name: (_) @_vimcmd_identifier
+  arguments: (arguments . (_) . (string content: _ @_method) . (string content: _ @injection.content)))
+  (#any-of? @_vimcmd_identifier "vim.rpcrequest" "vim.rpcnotify")
+  (#eq? @_method "nvim_exec_lua")
+  (#set! injection.language "lua"))
+
+;; highlight string as query if starts with `;; query`
+(string content: _ @injection.content 
+ (#lua-match? @injection.content "^%s*;+%s?query")
+ (#set! injection.language "query"))
+
+((comment) @injection.content
+  (#lua-match? @injection.content "^[-][-][-][%s]*@")
+  (#set! injection.language "luadoc")
+  (#set! injection.include-children)
+  (#offset! @injection.content 0 3 0 0))
+
+; string.match("123", "%d+")
+
+(function_call
+  (dot_index_expression
+    field: (identifier) @_method
+    (#any-of? @_method "find" "match"))
+  arguments: (arguments
+               . (_)
+               .
+               (string
+                 content: (string_content) @injection.content
+                 (#set! injection.language "luap")
+                 (#set! injection.include-children))))
+
+(function_call
+  (dot_index_expression
+    field: (identifier) @_method
+    (#any-of? @_method "gmatch" "gsub"))
+  arguments: (arguments
+               . (_)
+               .
+               (string
+                 content: (string_content) @injection.content
+                 (#set! injection.language "luap")
+                 (#set! injection.include-children))))
+
+;("123"):match("%d+")
+
+(function_call
+  (method_index_expression
+    method: (identifier) @_method
+    (#any-of? @_method "find" "match"))
+  arguments: (arguments
+               . (string
+                   content: (string_content) @injection.content
+                   (#set! injection.language "luap")
+                   (#set! injection.include-children))))
+
+(function_call
+  (method_index_expression
+    method: (identifier) @_method
+    (#any-of? @_method "gmatch" "gsub"))
+  arguments: (arguments
+               . (string
+                 content: (string_content) @injection.content
+                 (#set! injection.language "luap")
+                 (#set! injection.include-children))))
+
+((comment) @injection.content
+  (#set! injection.language "comment")
+  (#set! injection.include-children))

runtime/queries/lua/locals.scm

@@ -0,0 +1,51 @@
+; Scopes
+
+[
+  (chunk)
+  (do_statement)
+  (while_statement)
+  (repeat_statement)
+  (if_statement)
+  (for_statement)
+  (function_declaration)
+  (function_definition)
+] @scope
+
+; Definitions
+
+(assignment_statement
+  (variable_list
+    (identifier) @definition.var))
+
+(assignment_statement
+  (variable_list
+    (dot_index_expression . (_) @definition.associated (identifier) @definition.var)))
+
+((function_declaration
+  name: (identifier) @definition.function)
+  (#set! definition.function.scope "parent"))
+
+((function_declaration
+  name: (dot_index_expression
+    . (_) @definition.associated (identifier) @definition.function))
+  (#set! definition.method.scope "parent"))
+
+((function_declaration
+  name: (method_index_expression
+    . (_) @definition.associated (identifier) @definition.method))
+  (#set! definition.method.scope "parent"))
+
+(for_generic_clause
+  (variable_list
+    (identifier) @definition.var))
+
+(for_numeric_clause
+  name: (identifier) @definition.var)
+
+(parameters (identifier) @definition.parameter)
+
+; References
+
+[
+  (identifier)
+] @reference