benbot/nvim-treesitter
1
0
Fork 0
mirror of https://github.com/nvim-treesitter/nvim-treesitter.git synced 2026-07-05 21:10:15 -04:00
Code Issues Projects Releases Packages Wiki Activity Actions

feat!: drop modules, general refactor and cleanup

Browse source
This commit is contained in:
Christian Clason 2023-06-12 09:54:30 -06:00
parent c13e28f894
commit 2c8f2f2fad
829 changed files with 4905 additions and 8010 deletions
Download patch file Download diff file Expand all files Collapse all files

1
runtime/queries/jsx/folds.scm Normal file
View file

@ -0,0 +1 @@
(jsx_element) @fold

35
runtime/queries/jsx/highlights.scm Normal file
View file

@ -0,0 +1,35 @@
(jsx_element
open_tag: (jsx_opening_element ["<" ">"] @tag.delimiter))
(jsx_element
close_tag: (jsx_closing_element ["</" ">"] @tag.delimiter))
(jsx_self_closing_element ["<" "/>"] @tag.delimiter)
(jsx_attribute (property_identifier) @tag.attribute)
(jsx_opening_element
name: (identifier) @tag)
(jsx_closing_element
name: (identifier) @tag)
(jsx_self_closing_element
name: (identifier) @tag)
(jsx_opening_element ((identifier) @constructor
(#lua-match? @constructor "^[A-Z]")))
; Handle the dot operator effectively - <My.Component>
(jsx_opening_element ((member_expression (identifier) @tag (property_identifier) @constructor)))
(jsx_closing_element ((identifier) @constructor
(#lua-match? @constructor "^[A-Z]")))
; Handle the dot operator effectively - </My.Component>
(jsx_closing_element ((member_expression (identifier) @tag (property_identifier) @constructor)))
(jsx_self_closing_element ((identifier) @constructor
(#lua-match? @constructor "^[A-Z]")))
; Handle the dot operator effectively - <My.Component />
(jsx_self_closing_element ((member_expression (identifier) @tag (property_identifier) @constructor)))
(jsx_text) @none

16
runtime/queries/jsx/indents.scm Normal file
View file

@ -0,0 +1,16 @@
[
(jsx_element)
(jsx_self_closing_element)
(jsx_expression)
] @indent.begin
(jsx_closing_element (">" @indent.end))
(jsx_self_closing_element "/>" @indent.end)
[
(jsx_closing_element)
">"
] @indent.branch
; <button
; />
(jsx_self_closing_element "/>" @indent.branch)

9
runtime/queries/jsx/injections.scm Normal file
View file

@ -0,0 +1,9 @@
; Styled Jsx <style jsx>
(jsx_element
(jsx_opening_element
(identifier) @_name (#eq? @_name "style")
(jsx_attribute) @_attr (#eq? @_attr "jsx"))
(jsx_expression
((template_string) @injection.content
(#set! injection.language "css"))
(#offset! @injection.content 0 1 0 -1)))