feat!: drop modules, general refactor and cleanup

runtime/queries/javascript/folds.scm

@@ -0,0 +1 @@
+; inherits: ecma,jsx

runtime/queries/javascript/highlights.scm

@@ -0,0 +1,55 @@
+; inherits: ecma,jsx
+
+;;; Parameters
+(formal_parameters (identifier) @parameter)
+
+(formal_parameters
+  (rest_pattern
+    (identifier) @parameter))
+
+;; ({ a }) => null
+(formal_parameters
+  (object_pattern
+    (shorthand_property_identifier_pattern) @parameter))
+
+;; ({ a = b }) => null
+(formal_parameters
+  (object_pattern
+    (object_assignment_pattern
+      (shorthand_property_identifier_pattern) @parameter)))
+
+;; ({ a: b }) => null
+(formal_parameters
+  (object_pattern
+    (pair_pattern
+      value: (identifier) @parameter)))
+
+;; ([ a ]) => null
+(formal_parameters
+  (array_pattern
+    (identifier) @parameter))
+
+;; ({ a } = { a }) => null
+(formal_parameters
+  (assignment_pattern
+    (object_pattern
+      (shorthand_property_identifier_pattern) @parameter)))
+
+;; ({ a = b } = { a }) => null
+(formal_parameters
+  (assignment_pattern
+    (object_pattern
+      (object_assignment_pattern
+        (shorthand_property_identifier_pattern) @parameter))))
+
+;; a => null
+(arrow_function
+  parameter: (identifier) @parameter)
+
+;; optional parameters
+(formal_parameters
+  (assignment_pattern
+    left: (identifier) @parameter))
+
+;; punctuation
+(optional_chain) @punctuation.delimiter

runtime/queries/javascript/indents.scm

@@ -0,0 +1 @@
+; inherits: ecma,jsx

runtime/queries/javascript/injections.scm

@@ -0,0 +1 @@
+; inherits: ecma,jsx

runtime/queries/javascript/locals.scm

@@ -0,0 +1,63 @@
+; inherits: ecma,jsx
+
+; Both properties are matched here.
+;
+;   class Foo {
+;     this.#bar = "baz";
+;     this.quuz = "qux";
+;   }
+(field_definition 
+  property: [(property_identifier) (private_property_identifier)] @definition.var)
+
+; this.foo = "bar"
+(assignment_expression
+  left: (member_expression
+    object: (this)
+    property: (property_identifier) @definition.var))
+
+(formal_parameters
+  (identifier) @definition.parameter)
+
+; function(arg = []) {
+(formal_parameters
+  (assignment_pattern
+    left: (identifier) @definition.parameter))
+
+; x => x
+(arrow_function
+  parameter: (identifier) @definition.parameter)
+
+;; ({ a }) => null
+(formal_parameters
+  (object_pattern
+    (shorthand_property_identifier_pattern) @definition.parameter))
+
+;; ({ a: b }) => null
+(formal_parameters
+  (object_pattern
+    (pair_pattern
+      value: (identifier) @definition.parameter)))
+
+;; ([ a ]) => null
+(formal_parameters
+  (array_pattern
+    (identifier) @definition.parameter))
+
+(formal_parameters
+  (rest_pattern
+    (identifier) @definition.parameter))
+
+; Both methods are matched here.
+;
+;   class Foo {
+;     #bar(x) { x }
+;     baz(y) { y }
+;   }
+(method_definition
+  ([(property_identifier) (private_property_identifier)] @definition.function)
+   (#set! definition.var.scope parent))
+
+; this.foo()
+(member_expression
+  object: (this)
+  property: (property_identifier) @reference)