feat!: drop modules, general refactor and cleanup

runtime/queries/hcl/folds.scm

@@ -0,0 +1,6 @@
+[
+ (comment)
+ (block)
+ (heredoc_template)
+ (object)
+] @fold

runtime/queries/hcl/highlights.scm

@@ -0,0 +1,99 @@
+; highlights.scm
+
+[
+  "!"
+  "\*"
+  "/"
+  "%"
+  "\+"
+  "-"
+  ">"
+  ">="
+  "<"
+  "<="
+  "=="
+  "!="
+  "&&"
+  "||"
+] @operator
+
+[
+  "{"
+  "}"
+  "["
+  "]"
+  "("
+  ")"
+] @punctuation.bracket
+
+[
+  "."
+  ".*"
+  ","
+  "[*]"
+] @punctuation.delimiter
+
+[
+  (ellipsis)
+  "\?"
+  "=>"
+] @punctuation.special
+
+[
+  ":"
+  "="
+] @none
+
+[
+  "for"
+  "endfor"
+  "in"
+] @repeat
+
+[
+  "if"
+  "else"
+  "endif"
+] @conditional
+
+[
+  (quoted_template_start) ; "
+  (quoted_template_end); "
+  (template_literal) ; non-interpolation/directive content
+] @string
+
+[
+  (heredoc_identifier) ; END
+  (heredoc_start) ; << or <<-
+] @punctuation.delimiter
+
+[
+  (template_interpolation_start) ; ${
+  (template_interpolation_end) ; }
+  (template_directive_start) ; %{
+  (template_directive_end) ; }
+  (strip_marker) ; ~
+] @punctuation.special
+
+(numeric_lit) @number
+(bool_lit) @boolean
+(null_lit) @constant
+(comment) @comment @spell
+(identifier) @variable
+
+(body (block (identifier) @keyword))
+(body (block (body (block (identifier) @type))))
+(function_call (identifier) @function)
+(attribute (identifier) @field)
+
+; { key: val }
+;
+; highlight identifier keys as though they were block attributes
+(object_elem key: (expression (variable_expr (identifier) @field)))
+
+; var.foo, data.bar
+;
+; first element in get_attr is a variable.builtin or a reference to a variable.builtin
+(expression (variable_expr (identifier) @variable.builtin) (get_attr (identifier) @field))
+
+(ERROR) @error

runtime/queries/hcl/indents.scm

@@ -0,0 +1,15 @@
+[
+  (block)
+  (object)
+  (tuple)
+  (function_call)
+] @indent.begin
+
+[
+  "]"
+  ")"
+  "}"
+] @indent.branch @indent.end
+
+(comment) @indent.auto
+(ERROR) @indent.auto

runtime/queries/hcl/injections.scm

@@ -0,0 +1,7 @@
+((comment) @injection.content
+ (#set! injection.language "comment"))
+
+(heredoc_template
+  (template_literal) @injection.content
+  (heredoc_identifier) @injection.language
+  (#downcase! @injection.language))