feat!: drop modules, general refactor and cleanup

runtime/queries/haskell/folds.scm

@@ -0,0 +1,5 @@
+[
+ (exp_apply)
+ (exp_do)
+ (function)
+] @fold

runtime/queries/haskell/highlights.scm

@@ -0,0 +1,160 @@
+;; ----------------------------------------------------------------------------
+;; Literals and comments
+
+(integer) @number
+(exp_negation) @number
+(exp_literal (float)) @float
+(char) @character
+(string) @string
+
+(con_unit) @symbol  ; unit, as in ()
+
+(comment) @comment
+
+
+;; ----------------------------------------------------------------------------
+;; Punctuation
+
+[
+  "("
+  ")"
+  "{"
+  "}"
+  "["
+  "]"
+] @punctuation.bracket
+
+[
+  (comma)
+  ";"
+] @punctuation.delimiter
+
+
+;; ----------------------------------------------------------------------------
+;; Keywords, operators, includes
+
+[
+  "forall"
+  "∀"
+] @repeat
+
+(pragma) @preproc
+
+[
+  "if"
+  "then"
+  "else"
+  "case"
+  "of"
+] @conditional
+
+[
+  "import"
+  "qualified"
+  "module"
+] @include
+
+[
+  (operator)
+  (constructor_operator)
+  (type_operator)
+  (tycon_arrow)
+  (qualified_module)  ; grabs the `.` (dot), ex: import System.IO
+  (qualified_type)
+  (qualified_variable)
+  (all_names)
+  (wildcard)
+  "."
+  ".."
+  "="
+  "|"
+  "::"
+  "=>"
+  "->"
+  "<-"
+  "\\"
+  "`"
+  "@"
+] @operator
+
+(module) @namespace
+
+[
+  (where)
+  "let"
+  "in"
+  "class"
+  "instance"
+  "pattern"
+  "data"
+  "newtype"
+  "family"
+  "type"
+  "as"
+  "hiding"
+  "deriving"
+  "via"
+  "stock"
+  "anyclass"
+  "do"
+  "mdo"
+  "rec"
+  "infix"
+  "infixl"
+  "infixr"
+] @keyword
+
+
+;; ----------------------------------------------------------------------------
+;; Functions and variables
+
+(variable) @variable
+(pat_wildcard) @variable
+(signature name: (variable) @variable)
+
+(function
+  name: (variable) @function
+  patterns: (patterns))
+(function
+  name: (variable) @function
+  rhs: (exp_lambda))
+((signature (variable) @function (fun)) . (function (variable)))
+((signature (variable) @_type (fun)) . (function (variable) @function) (#eq? @function @_type))
+((signature (variable) @function (context (fun))) . (function (variable)))
+((signature (variable) @_type (context (fun))) . (function (variable) @function) (#eq? @function @_type))
+((signature (variable) @function (forall (context (fun)))) . (function (variable)))
+((signature (variable) @_type (forall (context (fun)))) . (function (variable) @function) (#eq? @function @_type))
+
+(exp_infix (variable) @operator)  ; consider infix functions as operators
+(exp_section_right (variable) @operator) ; partially applied infix functions (sections) also get highlighted as operators
+(exp_section_left (variable) @operator)
+
+(exp_infix (exp_name) @function.call (#set! "priority" 101))
+(exp_apply . (exp_name (variable) @function.call))
+(exp_apply . (exp_name (qualified_variable (variable) @function.call)))
+
+
+;; ----------------------------------------------------------------------------
+;; Types
+
+(type) @type
+(type_star) @type
+(type_variable) @type
+
+(constructor) @constructor
+
+; True or False
+((constructor) @boolean (#any-of? @boolean "True" "False"))
+
+
+;; ----------------------------------------------------------------------------
+;; Quasi-quotes
+
+(quoter) @function.call
+; Highlighting of quasiquote_body is handled by injections.scm
+
+;; ----------------------------------------------------------------------------
+;; Spell checking
+
+(comment) @spell
+

runtime/queries/haskell/injections.scm

@@ -0,0 +1,85 @@
+;; -----------------------------------------------------------------------------
+;; General language injection
+
+(quasiquote
+ ((quoter) @injection.language)
+ ((quasiquote_body) @injection.content)
+)
+
+((comment) @injection.content
+ (#set! injection.language "comment"))
+
+;; -----------------------------------------------------------------------------
+;; shakespeare library
+;; NOTE: doesn't support templating
+
+; TODO: add once CoffeeScript parser is added
+; ; CoffeeScript: Text.Coffee
+; (quasiquote
+;  (quoter) @_name
+;  (#eq? @_name "coffee")
+;  ((quasiquote_body) @injection.content
+;   (#set! injection.language "coffeescript")))
+
+; CSS: Text.Cassius, Text.Lucius
+(quasiquote
+ (quoter) @_name
+ (#any-of? @_name "cassius" "lucius")
+ ((quasiquote_body) @injection.content)
+ (#set! injection.language "css"))
+
+; HTML: Text.Hamlet
+(quasiquote
+ (quoter) @_name
+ (#any-of? @_name "shamlet" "xshamlet" "hamlet" "xhamlet" "ihamlet")
+ ((quasiquote_body) @injection.content)
+ (#set! injection.language "html"))
+
+; JS: Text.Julius
+(quasiquote
+ (quoter) @_name
+ (#any-of? @_name "js" "julius")
+ ((quasiquote_body) @injection.content)
+ (#set! injection.language "javascript"))
+
+; TS: Text.TypeScript
+(quasiquote
+ (quoter) @_name
+ (#any-of? @_name "tsc" "tscJSX")
+ ((quasiquote_body) @injection.content)
+ (#set! injection.language "typescript"))
+
+
+;; -----------------------------------------------------------------------------
+;; HSX
+
+(quasiquote
+ (quoter) @_name
+ (#eq? @_name "hsx")
+ ((quasiquote_body) @injection.content)
+ (#set! injection.language "html"))
+
+;; -----------------------------------------------------------------------------
+;; Inline JSON from aeson
+
+(quasiquote
+  (quoter) @_name
+  (#eq? @_name "aesonQQ")
+  ((quasiquote_body) @injection.content)
+  (#set! injection.language "json"))
+
+
+;; -----------------------------------------------------------------------------
+;; SQL
+
+; postgresql-simple
+(quasiquote
+  (quoter) @injection.language
+  (#eq? @injection.language "sql")
+  ((quasiquote_body) @injection.content))
+
+(quasiquote
+  (quoter) @_name
+  (#any-of? @_name "persistUpperCase" "persistLowerCase" "persistWith")
+  ((quasiquote_body) @injection.content)
+  (#set! injection.language "haskell_persistent"))