feat!: drop modules, general refactor and cleanup

runtime/queries/fusion/folds.scm

@@ -0,0 +1,6 @@
+[
+  (comment)
+  (block)
+  (afx_comment)
+  (afx_element)
+] @fold

runtime/queries/fusion/highlights.scm

@@ -0,0 +1,120 @@
+(comment) @comment
+(afx_comment) @comment
+
+; identifiers afx
+(afx_opening_element
+  (afx_identifier) @tag)
+(afx_closing_element
+  (afx_identifier) @tag)
+(afx_element_self_closing
+  (afx_identifier) @tag)
+
+(afx_attribute
+  (afx_property_identifier) @tag.attribute)
+
+(afx_text) @text
+
+; identifiers eel
+
+(eel_object_path
+  (eel_path_identifier) @variable.builtin
+  (#any-of? @variable.builtin "this" "props")
+)
+
+(eel_object_path
+  (eel_path_identifier) @variable)
+
+(eel_object_pair
+  key: (eel_property_name) @property)
+
+(eel_method_name) @function
+
+(eel_parameter) @variable
+
+; identifiers fusion
+; -----------
+
+(path_part) @property
+(meta_property) @attribute
+(prototype_signature
+  "prototype" @keyword
+
+)
+(include_statement
+  [
+   "include"
+  ] @include
+  (source_file) @text.uri
+)
+
+(namespace_declaration
+  "namespace" @keyword
+  (alias_namespace) @namespace)
+
+(type
+  name: (type_name) @type)
+
+; tokens
+; ------
+(afx_opening_element
+  [
+   "<"
+   ">"
+   ] @punctuation.bracket)
+
+ (afx_closing_element
+  [
+   "<"
+   ">"
+   "/"
+   ] @punctuation.bracket)
+
+(afx_element_self_closing
+  [
+   "<"
+   "/>"
+  ] @punctuation.bracket)
+
+[
+  (package_name)
+  (alias_namespace)
+] @namespace
+
+(namespace_declaration "=" @operator)
+(assignment "=" @operator)
+(copy "<" @operator)
+(deletion) @operator
+(eel_binary_expression
+  operator: _ @operator)
+(eel_not_expression
+  [
+   "!"
+   "not"
+  ] @operator)
+
+(string) @string
+(number) @number
+(boolean) @boolean
+(null) @constant.builtin
+
+(value_expression
+  start: _ @punctuation.special
+  end: _ @punctuation.special
+)
+[
+ "("
+ ")"
+ "{"
+ "}"
+ "["
+ "]"
+] @punctuation.bracket
+
+[
+ ":"
+ "."
+ "?"
+] @punctuation.delimiter
+
+(eel_ternary_expression
+  ["?" ":"] @conditional.ternary)

runtime/queries/fusion/indents.scm

@@ -0,0 +1,19 @@
+[
+  (block)
+  (value_dsl)
+  (afx_element)
+  (afx_element_self_closing)
+  (eel_array)
+  (eel_object)
+] @indent.begin
+
+
+(block end: _ @indent.branch)
+(value_dsl end: _ @indent.branch)
+(eel_array end: _ @indent.branch)
+(eel_object end: _ @indent.branch)
+[
+  (afx_closing_element)
+] @indent.branch
+
+(comment) @indent.ignore

runtime/queries/fusion/locals.scm

@@ -0,0 +1,21 @@
+;; Fusion base
+(block) @scope
+
+(namespace_declaration
+  (alias_namespace) @definition.namespace)
+
+(property
+  (path (path_part) @definition.field))
+
+(type
+  namespace: (package_name)? @definition.namespace
+  name: (type_name) @definition.type
+)
+
+;; Eel Expressions
+(eel_arrow_function) @scope
+(eel_object) @scope
+
+(eel_parameter) @definition.parameter
+(eel_object_pair
+  key: (eel_property_name) @definition.field)