feat!: drop modules, general refactor and cleanup

runtime/queries/fish/folds.scm

@@ -0,0 +1,8 @@
+[
+ (function_definition)
+ (if_statement)
+ (switch_statement)
+ (for_statement)
+ (while_statement)
+ (begin_statement)
+] @fold

runtime/queries/fish/highlights.scm

@@ -0,0 +1,168 @@
+;; Fish highlighting
+
+;; Operators
+
+[
+ "&&"
+ "||"
+ "|"
+ "&"
+ ".."
+ "!"
+ (direction)
+ (stream_redirect)
+] @operator
+
+;; match operators of test command
+(command
+  name: (word) @function.builtin (#eq? @function.builtin "test")
+  argument: (word) @operator (#match? @operator "^(!?\\=|-[a-zA-Z]+)$"))
+
+;; match operators of [ command
+(command
+  name: (word) @punctuation.bracket (#eq? @punctuation.bracket "[")
+  argument: (word) @operator (#match? @operator "^(!?\\=|-[a-zA-Z]+)$"))
+
+[
+ "not"
+ "and"
+ "or"
+] @keyword.operator
+
+;; Conditionals
+
+(if_statement
+[
+ "if"
+ "end"
+] @conditional)
+
+(switch_statement
+[
+ "switch"
+ "end"
+] @conditional)
+
+(case_clause
+[
+ "case"
+] @conditional)
+
+(else_clause 
+[
+ "else"
+] @conditional)
+
+(else_if_clause 
+[
+ "else"
+ "if"
+] @conditional)
+
+;; Loops/Blocks
+
+(while_statement
+[
+ "while"
+ "end"
+] @repeat)
+
+(for_statement
+[
+ "for"
+ "end"
+] @repeat)
+
+(begin_statement
+[
+ "begin"
+ "end"
+] @repeat)
+
+;; Keywords
+
+[
+ "in"
+ (break)
+ (continue)
+] @keyword
+
+"return" @keyword.return
+
+;; Punctuation
+
+[
+ "["
+ "]"
+ "{"
+ "}"
+ "("
+ ")"
+] @punctuation.bracket
+
+"," @punctuation.delimiter
+
+;; Commands
+
+(command
+  argument: [
+             (word) @parameter (#lua-match? @parameter "^[-]")
+            ]
+)
+
+(command_substitution "$" @punctuation.bracket)
+
+; non-builtin command names
+(command name: (word) @function.call)
+
+; derived from builtin -n (fish 3.2.2)
+(command
+  name: [
+        (word) @function.builtin
+        (#any-of? @function.builtin "." ":" "_" "alias" "argparse" "bg" "bind" "block" "breakpoint" "builtin" "cd" "command" "commandline" "complete" "contains" "count" "disown" "echo" "emit" "eval" "exec" "exit" "fg" "functions" "history" "isatty" "jobs" "math" "printf" "pwd" "random" "read" "realpath" "set" "set_color" "source" "status" "string" "test" "time" "type" "ulimit" "wait")
+        ]
+)
+
+;; Functions
+
+(function_definition ["function" "end"] @keyword.function)
+
+(function_definition
+  name: [
+        (word) (concatenation)
+        ] 
+@function)
+
+(function_definition
+  option: [
+          (word)
+          (concatenation (word))
+          ] @parameter (#lua-match? @parameter "^[-]")
+)
+
+;; Strings
+
+[(double_quote_string) (single_quote_string)] @string
+(escape_sequence) @string.escape
+
+;; Variables
+
+(variable_name) @variable
+(variable_expansion) @constant
+
+;; Nodes
+
+[(integer) (float)] @number
+(comment) @comment
+(comment) @spell
+
+((word) @boolean
+(#any-of? @boolean "true" "false"))
+
+((program . (comment) @preproc)
+  (#lua-match? @preproc "^#!/"))
+
+;; Error
+
+(ERROR) @error
+

runtime/queries/fish/indents.scm

@@ -0,0 +1,18 @@
+[
+ (function_definition)
+ (while_statement)
+ (for_statement)
+ (if_statement)
+ (begin_statement)
+ (switch_statement)
+] @indent.begin
+
+[
+ "else" ; else and else if must both start the line with "else", so tag the string directly
+ "case"
+ "end"
+] @indent.branch
+
+"end" @indent.end
+
+(comment) @indent.ignore

runtime/queries/fish/injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content 
+ (#set! injection.language "comment"))

runtime/queries/fish/locals.scm

@@ -0,0 +1,18 @@
+;; Scopes
+[
+  (command)
+  (function_definition)
+  (if_statement)
+  (for_statement)
+  (begin_statement)
+  (while_statement)
+  (switch_statement)
+] @scope
+
+;; Definitions
+(function_definition
+  name: (word) @definition.function)
+
+;; References
+(variable_name) @reference
+(word) @reference