feat(sproto): add parser

runtime/queries/sproto/folds.scm

@@ -0,0 +1,6 @@
+[
+  (type_definition)
+  (protocol_definition)
+  (request_block)
+  (response_block)
+] @fold

runtime/queries/sproto/highlights.scm

@@ -0,0 +1,47 @@
+(comment) @comment @spell
+
+[
+  "."
+  ":"
+] @punctuation.delimiter
+
+"*" @operator
+
+[
+  "request"
+  "response"
+] @keyword
+
+(type_definition
+  name: (identifier) @type)
+
+(nested_type_definition
+  name: (identifier) @type)
+
+(type_specifier) @type
+
+[
+  "integer"
+  "boolean"
+  "string"
+  "binary"
+  "double"
+] @type.builtin
+
+(protocol_definition
+  name: (identifier) @function)
+
+(field_definition
+  name: (identifier) @property)
+
+(map_specifier
+  key: (identifier) @property)
+
+(integer) @number
+
+[
+  "("
+  ")"
+  "{"
+  "}"
+] @punctuation.bracket

runtime/queries/sproto/indents.scm

@@ -0,0 +1,10 @@
+[
+  (type_definition)
+  (protocol_definition)
+  (request_block)
+  (response_block)
+] @indent.begin
+
+"}" @indent.end @indent.branch
+
+(comment) @indent.auto

runtime/queries/sproto/injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))